Open Object REXX (ooRexx)

Paradigm	Multi-paradigm: object-oriented (class-based), procedural (imperative), structured
Designed by	Simon C. Nash (IBM)
First appeared	1988; 36 years ago (1988)
Stable release	5.0.0 / 10 May 2023; 19 months ago (10 May 2023)
Preview release	5.1.0
Typing discipline	dynamic
Memory management	Garbage collection
Implementation language	C++
Platform	IA-32, x86-64, ARM, s390x
OS	Cross-platform: Linux, Microsoft Windows, macOS, Solaris, OpenIndiana, AIX, FreeBSD, OS/2
License	CPL 1.0, GPLv2
Filename extensions	.rxs, .rex, .rexx, .cls, .orx, .rexg, .rexp
Website	www.rexxla.org
Major implementations
Object REXX (until 2004) ooRexx (since 2005)
Influenced by
Rexx, Smalltalk
Influenced
NetRexx

Object REXX is a high-level, general-purpose, interpreted, object-oriented (class-based) programming language. Today it is generally referred to as ooRexx (short for “Open Object Rexx”), which is the maintained and direct open-source successor to Object REXX.

It is a follow-on and a significant extension of the Rexx programming language (often called "Classic Rexx"), retaining all the features and syntax while adding full object-oriented programming (OOP) capabilities and other new enhancements. Following its Classic Rexx influence, ooRexx is designed to be easy to learn, use, and maintain. It is essentially compliant with the "Information Technology – Programming Language REXX" ANSI X3.274-1996^[1] standard and therefore ensures cross-platform interoperability with other compliant Rexx implementations. Therefore, Classic Rexx programs typically run under ooRexx without any changes.

There is also Rexx Object Oriented (“roo!”), which was originally developed by Kilowatt Software and is an unmaintained object-oriented implementation of Classic Rexx.^[2]

In 1988, the "Oryx" project at IBM, under the technical direction of Simon C. Nash, experimented with merging Classic Rexx with the object model of Smalltalk.^[3][4] The motivation behind the project was to transfer the advantages of OOP to Classic Rexx while remaining compatible and thus transferring the usability of Classic Rexx to OOP.^[5] Early on, the projects focused on OOP aspect such as treating everything as an object, object-based encapsulation and message passing, object-based concurrency, classes and inheritance.^[6]

This initial work later led under the direction of Rick McGuire to the first prototype of Object REXX, which was presented in 1992. In 1994, IBM announced that Object REXX would replace Classic Rexx as the standard REXX interpreter in the next version of OS/2.^[4] In 1996, Object REXX^[a] was released as part of the OS/2 Warp 4 operating system.^[7] In 1997, versions for Windows 95, Windows NT and Linux followed.^[8][9] In 1999 an Object REXX version for AIX V4.1.5 or higher was released.^[10] In 2000, versions for zLinux and Sun/Solaris followed. For Windows 2000, Windows Me, Windows 98 and Windows NT 4.0, the last major update for Object REXX was released in 2001.^[11]

On 12 October 2004, IBM announced the discontinuation of Object REXX and transferred the source code and licensing rights^[b] to the non-profit Special Interest Group (SIG), the Rexx Language Association (RexxLA). The code that IBM released to open source did not include the classes for IBM System Object Model (SOM), which is known as the object framework for OS/2's Workplace Shell (WPS).^[12] Although IBM discontinued the development of SOM in 1997, it is still a fundamental framework for OS/2.^[13] The OS/2 version of Object REXX includes classes to support SOM and WPS.^[14][15] These are included in OS/2's initial follow-on product, eComStation, and also in its current descendant, ArcaOS, for which IBM's original Object REXX interpreter continues to be available.^[16]

In 2005, the RexxLA released ooRexx as a new incarnation of Object REXX as free and open-source software under the Common Public License.^[17] This first version of ooRexx 3.0.0 has been heavily refactored compared to the original IBM source code in order to increase readability. Later, the ooRexx kernel was rewritten in pure C++, and a new architecture and native interface were designed and implemented under the technical direction of Rick McGuire. This work enabled the RexxLA to release ooRexx 4.0.0 with support for 64-bit in 2009. To this day, the RexxLA continues to develop, support and maintain ooRexx as well as Classic Rexx and NetRexx. Furthermore, the RexxLA organizes international annual symposia.^[18]

The following table contains noteworthy features and changes of major Object REXX and ooRexx interpreter versions. All ooRexx releases and the necessary documentation are available freely on Sourceforge.^[19][20] For Arch Linux based distributions the current and the development version are available as Arch User Repository. Since version 5.0.0 there are portable versions of the interpreter that can be used without installation, and an unofficial port to OS/2 also exists. For Intellij IDEA, the ooRexxPlugin adds support for syntax highlighting, syntax checking, code completion and documentation support modeled after Javadoc using annotations.^[21]

ooRexx follows the design philosophy of Classic Rexx to create a "human-centered" programming language that is easy to learn, code, remember and maintain. This is achieved, in part, by keeping the language small and following the principle of least astonishment.^[2][29] A readable syntax is enabled by being case-insensitive, free-form, requiring as little punctuation as possible, and using instructions that are straightforward English.^[29] In addition, it is a dynamic programming language that offers flexibility and allows to focus on development rather than language constraints.

Following the "documentation before implementation" design principle of Classic Rexx, ooRexx offers comprehensive documentation in accordance with the IBM Style Guide that includes syntax diagrams and examples.^[29][30]

As in Classic Rexx, there are assignment instructions, keyword instructions and command instructions. In line with the desire to keep the language small, there are only thirty keyword instructions in ooRexx 5.0.0.^[30] Unlike many other languages, no keywords are reserved, so there is no need to memorize a long list of reserved words.^[31] In cases where an instruction is neither an assignment nor a keyword instruction, it must be a string literal or a valid expression which is considered a command instruction, which causes the interpreter to pass the string to the operating system for execution and set a variable RC for the return code. In addition, the ADDRESS instruction allows commands to be redirected to specific command environments such as Bourne Shell, Bash, Z-Shell, Command Prompt and others, some editors including ISPF, TSO EDIT, XEDIT and its adaptations, as well as intercepting errors.

a = "hello world"           /* assignment instruction           */
do i = 1 to 2               /* keyword instruction "DO"         */
  say "round #" i":" a      /* keyword instruction "SAY"        */
end                         /* keyword instruction "END"        */
"echo Hello World"          /* command to operating system      */
say "RC:" rc                /* command's numeric return code    */

In addition to the three instruction types of Classic Rexx, ooRexx adds directive^[c] instructions which need to be placed at the end of the program. After loading and the syntax check, the interpreter executes all defined directives to set up the execution environment for the program before further instructions are executed. Directives can be used to define routines, classes, methods, attributes or execution options like the number of digits to use in arithmetics. To make directive instructions readily recognizable, they are introduced with two consecutive colons (::).^[30]

To facilitate the reusability of code, the ::REQUIRES directive allows the integration of another Rexx program (also known as a package) or an external (native) library. This directive causes the interpreter to make every routine and class that specifies the PUBLIC option of the denoted Rexx program (package) to become directly accessible. External packages usually use the file extension .cls, for example ::requires "csvstream.cls" or ::requires "json.cls". Some external packages and libraries are delivered with the ooRexx interpreter.

ooRexx has a free-form syntax where the positioning of the program code is irrelevant, which allows a high degree of flexibility. Before execution, the interpreter merges multiple unquoted blanks into one, while a character string enclosed in quotation marks (single or double) is not changed. Concatenation can be requested explicitly with two vertical bars (||), or implicitly by separating terms with spaces or by abutting terms. Optionally, clauses can be spread over several lines by using the comma (,) or the minus sign (-) as a continuation character, or several clauses can be used in a single line, separated by a semicolon (;).^[30] Since a free-form language provides flexibility and requires fewer syntactic rules to be considered, it is assumed that it eases the learning effort by reducing the intrinsic cognitive load.^[32]

say   "Hello World!"        /* output: Hello World!             */
say "   This"     'is' -    /* trailing dash for continuation   */
        "REXX"   || "!"     /* output:    This is REXX!         */

As Classic Rexx, ooRexx is a case-insensitive programming language. The interpreter capitalizes all characters outside quotation marks before executing them. Because the cases do not need to be differentiated, fewer additional details need to be learned and frustrating syntax errors are avoided.^[32]

a = "This is REXX!"
Say A                       /* output: This is REXX!  */
SAY a                       /* output: This is REXX!  */

While Classic Rexx follows the "Everything is a String" philosophy and has string as its only data type, ooRexx considers everything as objects, including non-string objects such as arrays, streams and many more. Objects are manipulated using methods instead of traditional functions.

In ooRexx, a string variable is a reference to a string object and does not need to be declared, which reduces the effort for programmers compared to strictly typed languages.^[33] A string object can be of any length and contain any characters, including numerical values. It is therefore possible to change numerical values with string manipulations and methods of the String class. In addition, a string variable can contain any type of expression, including executable instructions, which can be evaluated or executed with the INTERPRET keyword instruction.^[30]

a = 2                               /* string with numerical value      */
a = a || '0'                        /* resulting string: 20             */

str = "do i = 1 to "a"; say i; end" /* string contains loop instruction */
interpret str                       /* interpret string: counts to 20   */

Similar to the messaging paradigm implemented by Alan Kay in Smalltalk, everything in ooRexx is an object that can be communicated with. The notion of sending messages to objects as if they were living beings helps beginners to learn OOP concepts.^[31] In contrast to Smalltalk, there is an explicit message operator, the tilde (~), where the receiving object is placed to the left of it and the result of the operation is returned. Sending a message leads to the activation of a method with the corresponding method name and to the manipulation of the receiving object. Like Smalltallk, ooRexx messages can be cascaded if two tildes (~~) are used instead of one, returning the object that received the method rather than the result produced.^[34]

The default behavior of most methods can be changed by specifying an option, which can be either spelled out or abbreviated and is not case-sensitive. When reading code, this enables a literal understanding and reduces the learning effort for beginners, as there is no need to learn the meaning of abbreviations.^[32] For example, the method with the name strip removes leading and trailing blanks by default. This behavior can be changed, for example, by specifying "leading" or "l" as an option. While functions are nested in Classic Rexx, messages can be chained in ooRexx, which improves the readability of a statement.^[31]

a = "   I am ooRexx!"
say a                           /* output:    I am ooRexx! */
say a~Strip("Leading")          /* output: I am ooRexx!    */
say a~strip("l")~reverse        /* output: !xxeRoo ma I    */

ooRexx is designed to retain all the features of Classic Rexx and essentially complies with the ANSI standard for the Rexx language (X3.274-1996, "Programming Language REXX").^[1] In contrast to an optional specification in the ANSI standard, ooRexx does not allow characters such as @, #, $ and ¢ in symbols. While in Classic Rexx the expression b. = a. results in b. being assigned the default value of a., the interpreter makes b. an alias for a.. In addition, ooRexx allows -- as a comment mark and - as a line continuum, which are not specified in the standard.^[1]

Classic Rexx scripts usually run without changes under ooRexx, making it easy to migrate to OOP features at the desired rate while preserving the time invested in the original code.^[2] As the interpreter supports a large number of platforms, code migration to these is also feasible.

Above all, ooRexx offers OOP features such as subclassing, polymorphism, data encapsulation and multiple inheritance via mixin classes. The interpreter includes the rexxc utility, which makes it possible to compile ooRexx programs and optionally encode the result as base64, a source-less file that starts faster since the initial parsing and compiling has already been done.^[34]

The PARSE keyword instruction makes it possible to quickly and flexibly parse a string and assign parts of it to variables in a single step.^[2] Subsequent instruction is used to specify the source of the string, for example ARG for arguments that are listed when the program or function is called, VAR for variables, PULL for data queues or standard input (typically the keyboard), VALUE for any expression. When using VALUE, the WITH keyword is required to specify the end of an expression, followed by a parsing pattern. This pattern can be a list of variables, a position number or literal delimiters; it is possible to use these patterns in combination. Optionally, the upper and lower case of the string can be converted before parsing.^[30]

str = "Person: Rick McGuire" 
/* parse string using the literal ":" and blanks between words 
   into variables a ("Person"), b ("Rick"), and c ("McGuire")   */
parse var str a ":" b c         /* parse by literal and blank   */
say b c                         /* output: Rick McGuire         */

ooRexx provides a new way to define procedures and functions that are not specific to a particular class by using the ::ROUTINE directive. The CALL instruction can be used to invoke a routine as a procedure. In addition, routines that return values via the RETURN keyword instructions can be called using function calls by specifying the name of the routine followed by brackets. The content within the brackets is passed as an argument to a routine. The PARSE instruction can be used to parse the received arguments and assign them to variables.^[30]

call DoSomething                    /* "CALL" keyword instruction       */
Sum = myFunction("2","4")           /* function call                    */
say Sum                             /* output: 6                        */

::Routine DoSomething               /* "ROUTINE" directive (procedure)  */
  say "I did something!"            /* output: I did something!         */

::Routine myFunction                /* "ROUTINE" directive (function)   */
  parse arg FirstVar, SecondVar     /* assign arguments to variables    */
  Sum = FirstVar + SecondVar        /* do calculation                   */
  return Sum                        /* "RETURN" result                  */

The ::CLASS directive followed by a class name causes the interpreter to define a new class. After the class name, options such as METACLASS, SUBCLASS, MIXINCLASS, ABSTRACT and INHERIT can be set in order to use OOP features. The ::METHOD directive can be used to define a new class method that is associated with the last ::CLASS directive. The ::ATTRIBUTE directive is used to define an accessor method that can retrieve or assign an object variable. Using the EXPOSE instruction, an object variable can be directly exposed to a method.^[30]

d = .dog~new("Bella")           /* create and assign a dog  */
d~bark                          /* send bark message        */
say d~name                      /* output: Bella            */

::class dog                     /* class directive          */
::attribute name                /* attribute directive      */
::method init                   /* object initiation method */
  Expose name                   /* exposes name of dog      */
  Parse arg name                /* assigns "Bella" to name  */
::method bark                   /* method directive         */
  Expose name
  say Name "goes woof!"         /* output: Bella goes woof! */

Conceptually, ooRexx provides object-based concurrency, according to which objects have independent resources to execute methods and can communicate with each other using the messaging paradigm. Several objects can be active at the same time and exchange messages for synchronization.^[30] Concurrency can be achieved with the REPLY keyword instruction, which causes an early return from a method while its remainder continues to execute in a new thread. Alternatively, the keyword instruction GUARD can be used to mark a method as unprotected so that it can be executed together with other methods of the same class. Finally, using the START method (Object or Message class) causes the recipient to process the received message in a separate thread, thus also enabling concurrency.^[30]

As in Classic Rexx, the TRACE keyword statement and the built-in TRACE() function facilitate debugging. Both allow control over the level of detail and enable interactive debugging at runtime.^[35] When interactive debugging, the interpreter pauses after most instructions that are traced.^[30] ooRexx 5.1.0 introduces the TraceObject class, which provides additional information such as timestamps, interpreter instances, thread IDs on which messages are dispatched, and the state of the guard locks for tracing multi-threaded programs. This class makes it easier to determine which method is currently guarded and blocked.^[35]

As ooRexx aims to be compatible with Classic Rexx, the traditional built-in functions are still available.^[34] Release 5.0.0 provides 82 built-in functions, including character manipulation, conversion and information functions, many of which call methods of the String class. In addition, the built-in dynamic link library RexxUtil offers 29 cross-platform, 25 Windows-specific and four Unix-specific functions for manipulating system files, directories, classes and objects.^[30]

In keeping with its object-oriented roots, ooRexx provides most of its functionality via built-in classes and methods. ooRexx 5.0.0 is delivered with a total of 57 built-in classes, which are divided into the class groups Fundamental, Stream, Collection and Utility.^[30]

Fundamental classes are the essential building blocks for all other classes. The Object class is the root of the class hierarchy, so that its methods and attributes are available for all instantiated objects of each class. The Class class (a.k.a. meta class) is used to maintain the properties of a class (like its method objects) and gets used for creating instances (a.k.a. objects, values). Therefore, an instance of this class (a.k.a. class object) is created for each ::CLASS directive.^[30] The purpose of the Method class and Routine class is to create method or routine objects. The String class provides methods for handling strings, such as logical operations, concatenation, copying, joining, splitting, reversing, arithmetic, conversion, and others.^[34] A Package class instance contains all created routines, classes, and methods and manages external dependencies referenced by ::REQUIRES directives. The Message class enables the asynchronous sending of messages, which enables the concurrent execution of methods.^[30][34]

Stream classes facilitate communication with external objects such as files, queues, serial interfaces, devices, etc. The Stream class itself is a mixin class that can be inherited and is a subclass of the InputOutputStream, InputStream, and OutputStream classes.^[30]

The Stream class provides methods for opening, reading, writing, and closing streams and flushing buffers, setting the file location, retrieving information, and other stream-related operations. While the OPEN method opens the stream, the ARRAYIN method can be used to read its content into an array object. The CLOSE method explicitly closes a stream before the stream object is reclaimed by the garbage collector.^[30][34]

StreamObj = .stream~new("someFile.txt")     /* create stream object */
StreamObj~open                              /* open the stream      */
FileContent = StreamObj~ArrayIn             /* read content         */
StreamObj~close                             /* close the stream     */

say FileContent                             /* outputs content      */

A collection is an object that contains multiple items with associated indexes that enable items to be retrieved using the AT or [] methods. There are MapCollection, SetCollection and OrderedCollection classes, all of which allow manipulation of a specific collection type.^[34]

A MapCollection is a mixin class that defines the basic set of methods implemented by all collections that map from an index to a value. The Directory, StringTable, IdentityTable, Properties, Table, Relation and Stem classes inherit these methods.^[30] A Directory or a StringTable object is a collection of unique string indexes. In an IdentityTable object, each item is associated with a single index, and there can only be one item for each index. The Properties object provides specific methods for saving and loading properties into files. Unlike a Table object, which cannot contain duplicate indexes, a Relation object is a collection in which elements can have the same index, which can be of any object type.

A Stem object is created automatically when a compound variable is used. As in Classic Rexx, such a variable consists of a stem and a tail, separated by a dot (.). While the stem must begin with a letter, the tail can be any character. Using a single numeric tail creates the same effect as an array, while multiple numeric tails can be used to create a multidimensional array.^[30][34]

fruits.1 = "Apple"          /* assigning to stem variable */
fruits.4 = "Orange"         /* assigning to stem variable */
say fruits.4                /* output: Orange             */
say fruits.[1]              /* output: Apple              */

SetCollections are special types of MapCollections where the index and the element are the same object. While the indexes in a Set object are unique, each index in a Bag object can appear more than once.^[30]

An OrderedCollection is a mixin class that defines the basic methods for all collections that have an inherent index order, such as the List, Queue, CircularQueue and Array classes. A List object allows new items, for which a new index is created, to be added at any position in a collection. The associated index remains valid for that item regardless of other additions or removals. A Queue object allows items to be removed from the head and added to the tail or head of the queue. A CircularQueue object is a queue with a predefined size. Once the end of the circular queue is reached, new elements are inserted from the beginning to replace the previous items.^[30][34]

An Array is sequenced collection ordered by whole-number indexes. Like some other collection classes, the Array class provides the MAKESTRING method to encode its elements as a string object.^[30]

ArrayObj = .array~of("One", "Two", "Three") /* array with 3 items      */
say ArrayObj~at(2)                          /* output: Two             */
say ArrayObj~makeString(,"; ")              /* output: One; Two; Three */

Utility classes are a collection of 31 classes that provide implementations for common tasks. The MutableBuffer class enables greater efficiency in string operations such as concatenation, as no new object needs to be assigned. The File class provides methods for listing files in a directory or retrieving information about files and directories.^[30]

FileObj = .File~new("~/someFolder/") /* create file object for folder   */
FileArr = FileObj~ListFiles          /* retrieve array of files         */

do FilePath over FileArr             /* iterate over the array items    */
    say FilePath                     /* output: FilePath item           */
end

The DateTime or TimeSpan classes support the retrieval and formatting of a date, time or timestamp in various formats and enable arithmetic operations between them. Several Comparator classes facilitate sorting for built-in classes such as File, DateTime and others. The class Supplier and its subclass StreamSupplier enable the enumeration of an items collection together with an indexes collection. The Validate class provides methods that can be used to check whether given arguments are of the correct class and type, or within a numerical range. A VariableReference instance maintains a reference, while a WeakReference instance creates a reference to another object that is not pinned.^[30]

A regular expression is a pattern that can be used to match strings. To increase the readability of patterns in the code, the RegularExpression class allows the use of symbolic names encapsulated with colons (:) for common sets. For instance, matching a string containing only letters typically described as [A-Za-z] can be abbreviated using [:alpha:].^[30]

Other classes help to obtain information about the context of the currently executed code (RexxContext), the Rexx language or the executing platform (RexxInfo) and execution specifics (StackFrame) via environment symbols. The Buffer and Pointer classes are specifically designed to support writing methods and function in native code using the C/C++ APIs. Alarm and Ticker classes provide notification functions and EventSempahore and MutexSempahore classes implement synchronization mechanisms for multi-threading activities. The Monitor class enables messages to be forwarded to various target objects and the RexxQueue class provides object-like access to external Rexx data queues.^[30]

Using the ::REQUIRES directive and specifying the LIBRARY option, external libraries can be integrated per program. Such libraries are usually organized around domain-specific functions.^[30]

The Rexx extension library offers classes for reading and writing comma-separated values (CSV) files, as well as for creating and processing JavaScript Object Notation (JSON) data. A library called “hostemenu” is also included, which partially emulates a TSO/CMS environment.^[36] The RxSock native library enables to incorporate TCP/IP protocols,^[37] while the RxFtp native library^[38] specifically provides access to the file transfer protocol (FTP). The RxMath native library offers advanced mathematical functions such as square root calculation, exponential function, logarithm, sine, cosine, tangent, arc sine and power calculation.^[39]

Say rxcalcsin(1)                /* output: 0.0174524064     */

::requires 'rxmath' LIBRARY     /* load a native library    */

For Windows, ooRexx includes the ooDialog framework allowing to produce Windows dialogs and therefore graphical user interfaces.^[40] The interpreter is delivered with several example programs and function packages that demonstrate the use of this framework.^[34] For POSIX-compatible operating systems, the orxnCurses class library enables the writing of text-based user interfaces using the ncurses programming library.^[41] The RxUnixSys library provides functions on most Unix systems for interacting with processes and threads, users and user groups, files and file systems and other.^[42]

Many of these external packages and libraries are also compatible with other Rexx implementations.

While ooRexx compared to Object REXX no longer contains classes for SOM and WPS support, it offers application programming interfaces (APIs) for interacting with code written in C or C++.^[43] There is also an external library that implements a bidirectional Java bridge, which enables interaction between ooRexx and Java.^[31] Furthermore, classes are provided that enable the automation of Windows applications. The ooSQLite class provides an interface to SQLite, an in-process library that implements a self-contained, serverless, zero-configuration, transactional SQL database engine.^[44] It allows interaction with several variants of SQL databases without having to change the script, but multi-threading is not supported.^[45]

As Classic Rexx, ooRexx includes APIs for extending Rexx with applications written in C and vice versa. This enables the creation of handlers for subcommands used in Rexx programs that run as application macros, external functions that allow a direct extension of the ooRexx function set and system functions that allow the behavior of the interpreter to be customized.^[43]

With ooRexx 4.0.0 APIs have been introduced that allow C++ applications to extend ooRexx and vice versa. This includes handlers for methods and functions written in C++ that extend ooRexx, both packaged as external libraries. These are dynamic link libraries on Windows or as shared libraries on Unix-based systems. An external library can be loaded with the ::REQUIRES directive or by using the EXTERNAL keyword instruction as part of a ::ROUTINE, ::METHOD, or ::ATTRIBUTE directive.

Using the C++ APIs, BSF4ooRexx was developed as a bidirectional Java bridge based on the Bean Scripting Framework. This bridge enables ooRexx to communicate with Java objects and Java to interact with Rexx applications.^[46][47] The bridge is realized by requiring the ooRexx package BSF.CLS, which defines public routines, classes and the environment symbol .BSF4REXX.^[47] Examples are provided for the use of Java classes in connection with AWT, Swing, JavaFX, JDBC, Java 2D and some others.^[46]

/* create Java object */
frame=.bsf~new("javax.swing.JFrame", "Hello, my beloved world - from ooRexx!")

frame~setSize(410,20)                           /* set width and height	      */
frame~visible=.true                             /* make JFrame visible     	  */
call SysSleep 10                                /* sleep for ten seconds      */

::requires "BSF.CLS"                            /* get Java support           */

Based on BSF4ooRexx, interaction with Universal Network Objects (UNO), as used in OpenOffice and LibreOffice, is supported via the UNO.CLS package.^[48] In addition, the CLR.CLS package together with Jini4Net enables the use of the .NET framework.^[49] Communication with processes via the D-Bus middleware under Linux is possible using the DBUS.CLS package.^[50]

The Windows extension includes the Windows Script Host (WSH) Scripting Engine that can be used to perform general automation tasks. It also includes Object Linking and Embedding/ActiveX (OLE) support allowing to interact with Windows programs via the OLEObject.^[51] OLE Automation is an inter-process communication mechanism developed by Microsoft that is based on a subset of the Component Object Model (COM). This mechanism enables, among other things, the invocation of program functions, the querying and setting of attributes and the interception of component events. The ooRexx interpreter comes with examples that demonstrate OLE interaction with Access, Word, Excel, OpenOffice/LibreOffice, ActiveDirectory, WMI and other programs. Furthermore, a utility program for searching available OLE objects is included.^[34]

exc = .OLEObject~new("Excel.Application")     /* create object for Excel */
exc~visible = .true                           /* make Excel visible      */
Worksheet = exc~Workbooks~Add~Worksheets[1]   /* add worksheet           */
Worksheet~cells(1,1)~Value = “First Cell”     /* insert string into cell */

In addition to OLE support, the Windows extension enables interaction with the Windows program manager, the system event log, the clipboard and the registry as well as to query, edit and interact with windows, menus or sub-menus.^[51]

• Comparison of programming languages
• Timeline of programming languages
• REXX
• NetRexx

• Ashley, W. David; Flatscher, Rony G.; Hessling, Mark; McGuire, Rick; Peedin, Lee; Sims, Oliver; Wolfers, Jon (2022). ooRexx Documentation 5.0.0 Open Object Rexx Reference (PDF). RexxLA.
• Ashley, W. David; Flatscher, Rony G.; Hessling, Mark; McGuire, Rick; Peedin, Lee; Sims, Oliver; Wolfers, Jon (2022). ooRexx Documentation 5.0.0 Programmer Guide (PDF). RexxLA.
• Ashley, W. David; Flatscher, Rony G.; Hessling, Mark; McGuire, Rick; Peedin, Lee; Sims, Oliver; Sims, Oliver; Wolfers, Jon (2022). ooRexx Documentation 5.0.0 Windows Extensions Reference (PDF). RexxLA.
• Ashley, W. David; Flatscher, Rony G.; Hessling, Mark; McGuire, Rick; Peedin, Lee; Sims, Oliver; Wolfers, Jon (2022). ooRexx Documentation 5.0.0 Application Programming Interfaces (PDF). RexxLA.
• Fosdick, Howard (2024). Rexx Programmer's Reference (PDF) (2nd ed.). Rexx Language Association. ISBN 978-9-40374-552-7.
• Flatscher, Rony G. (2024). Introduction to Rexx and ooRexx: From Rexx to Open Object Rexx (ooRexx). Mijnbestseller. ISBN 978-9403755038.

• Rexx Language Association
• Open Object Rexx 5.0.0 documentation
• Open Object Rexx on Sourceforge
• Open Object Rexx Website
• Open Object Rexx on Rosetta Code
• BSF4ooRexx on Sourceforge